data toyexample;
/*********************** Display 8.22 ***************************/
  input literacy @@;

/* method 1-2:
Boolean trick to assign category labels 1-4;
  If a logical comparison is TRUE (FALSE), it evaluates to 1 (0)
  e.g. if literacy=54, (53<literacy<=76)=TRUE while
      (0<literacy<=53)=(76<literacy<=90)=(90<literacy<=100)=FALSE
       And so cat_literacy = 1*0 + 2*1 + 3*0 + 4*0 = 2
*/

cat_literacy1 = 1*(0<literacy<=53) + 2*(53<literacy<=76)
              + 3*(76<literacy<=90) + 4*(90<literacy<=100);

cat_literacy2 = 1*(literacy<=53) + 2*(53<literacy<=76)
              + 3*(76<literacy<=90) + 4*(90<literacy<=100);

/*
method 3:
   First check for nonmissing and valid ranges before Boolean trick
*/
if ( (literacy NE .) AND (0<=literacy<=100) ) then
cat_literacy3 = 1*(literacy<=53) + 2*(53<literacy<=76)
              + 3*(76<literacy<=90) + 4*(90<literacy<=100);

/* method 4:
IF-THEN-ELSE blocks to assign category labels
*/
if ( (literacy EQ .) OR (100<literacy)
   OR (literacy<0) ) then cat_literacy4=.;
else if (literacy <=53) then cat_literacy4=1;
else if (literacy <=76) then cat_literacy4=2;
else if (literacy <=90) then cat_literacy4=3;
else cat_literacy4=4;

/* method 5A:
IF-THEN-ELSE blocks to assign category labels
*/
if (0<literacy <=53) then cat_literacy5A=1;
   else if (literacy <=76) then cat_literacy5A=2;
   else if (literacy <=90) then cat_literacy5A=3;
   else cat_literacy5A=4;

/* method 5B:
IF-THEN-ELSE blocks to assign category labels
*/
if (literacy <=53) then cat_literacy5B=1;
   else if (literacy <=76) then cat_literacy5B=2;
   else if (literacy <=90) then cat_literacy5B=3;
   else cat_literacy5B=4;

datalines;
-99 25.55 73.7 83 99.9 107 .
;
run;
ods rtf file="C:\Users\baileraj\Desktop\Display-8-22.rtf";
proc print data=toyexample;
run;
ods rtf close;

data toyexample2; set toyexample;
  format literacy literacyfmt.;
run;

ods rtf file="C:\Users\baileraj\Desktop\Display-8-05.rtf";
proc print data=toyexample2;
run;

proc means data=toyexample2;
var literacy literacy_too;
run;

ods rtf close;